* This file is langevineef1.inp.
* Usage, charmm <langevineef1.inp >langevineef1.out.
* Runs Langevin dynamics with eef1 implicit water.
*

! Open and read topology and parameter files for eef1 representation.
open read card name "toph19_eef1.inp" unit 20
read rtf card unit 20
close unit 20

open read card name "param19_eef1.inp" unit 20
read parameter card unit 20
close unit 20

! Read sequences and coordinates from the pdb file.
open read card name "domain.pdb" unit 21
read sequence pdb unit 21
generate prot setup
rewind unit 21

read coordinate pdb offset -6 unit 21
close unit 21

! Add missing atoms
ic fill preserve
ic parameter
ic build
hbuild

open write card name lang.psf unit 31
write psf card unit 31
*psf of arm
*

system -
"echo Finished adding atoms  > /dev/tty"

! Set frictional coefficient for Langevin.
scalar fbeta set 1 select all end

! Setup for EEF1 
eef1 temp 300 name solvpar.inp unit 93
update ctonnb 7. ctofnb 9. cutnb 10. group rdie

minimize abnr nstep 1000 nprint 100

open write card name "before.pdb" unit 41
write coordinate pdb select all end unit 41
* Coordinates before langevin dynamics
*

system -
"echo Starting simulation  > /dev/tty"

open write file name "langevin.dcd" unit 32

! Heating dynamics
dynamics leap langevin strt -
 nstep 200000 timestep 0.002 -
 nprint 100 nsavc 100 -
 ilbfrq 500 rbuf 0 tbath 300 -
 firstt 300 finalt 300 twindl -50 twindh 50 -
 nsavv 0 inbfrq -1 iprfrq 100  -
 iunrea -1 iunwri -1 iuncrd 32 iunvel -1 kunit -1 -
 iasors 0 iasvel 1 iscvel 0 ichecw 0 - 
!  iasors 1 iasvel 1 ichew 0 
 echeck 100  

system -
"echo Ran Langevin > /dev/tty"

open write card name "after.pdb" unit 41
write coordinate pdb select all end unit 41
* Coordinates after langevin dynamics
*
stop